Gecko [ actualbuzz.com ]

Name	Size	Permission	Date
_bluetoothctl	2.35 KB	-rw-r--r--	2022-11-10 20:24
_bootctl	2.84 KB	-rw-r--r--	2022-10-31 18:59
_busctl	9.36 KB	-rw-r--r--	2022-10-31 18:59
_bwrap	6.18 KB	-rw-r--r--	2024-08-12 18:00
_coredumpctl	1.89 KB	-rw-r--r--	2022-10-31 18:59
_curl	14.58 KB	-rw-r--r--	2026-01-28 08:27
_firewalld	20.25 KB	-rw-r--r--	2026-03-10 23:36
_flatpak	643 B	-rw-r--r--	2024-04-17 17:19
_hostnamectl	2.73 KB	-rw-r--r--	2022-10-31 18:59
_journalctl	7.03 KB	-rw-r--r--	2022-10-31 18:59
_kernel-install	779 B	-rw-r--r--	2022-10-31 18:59
_libinput	8.18 KB	-rw-r--r--	2021-12-13 03:43
_localectl	3.68 KB	-rw-r--r--	2022-10-31 18:59
_loginctl	6.25 KB	-rw-r--r--	2022-10-31 18:59
_nvme	102.57 KB	-rw-r--r--	2025-04-11 11:26
_pcp	63.79 KB	-rw-r--r--	2025-09-22 09:40
_podman	7.64 KB	-rw-r--r--	2026-02-25 16:33
_sd_hosts_or_user_at_host	128 B	-rw-r--r--	2022-10-31 18:59
_sd_machines	505 B	-rw-r--r--	2022-10-31 18:59
_sd_outputmodes	318 B	-rw-r--r--	2022-10-31 18:59
_sd_unit_files	263 B	-rw-r--r--	2022-10-31 18:59
_systemctl	19.5 KB	-rw-r--r--	2026-05-05 15:47
_systemd	3.76 KB	-rw-r--r--	2022-10-31 18:59
_systemd-analyze	5.5 KB	-rw-r--r--	2026-05-05 15:44
_systemd-delta	633 B	-rw-r--r--	2022-10-31 18:59
_systemd-inhibit	1.15 KB	-rw-r--r--	2022-10-31 18:59
_systemd-path	330 B	-rw-r--r--	2022-10-31 18:59
_systemd-run	4.25 KB	-rw-r--r--	2022-10-31 18:59
_systemd-tmpfiles	744 B	-rw-r--r--	2022-10-31 18:59
_timedatectl	2 KB	-rw-r--r--	2022-10-31 18:59
_udevadm	8.06 KB	-rw-r--r--	2022-10-31 18:59

Rename

#compdef bluetoothctl

__bluetoothctl() {
	bluetoothctl "$@" 2>/dev/null
}

_bluezcomp_controller() {
	local -a controllers
	bluetoothctl list |
	while read _ MAC NAME; do
		controllers+="${MAC//:/\\:}:${NAME//:/\\:}"
	done
	_describe -t controllers 'controller' controllers
}

_bluezcomp_device() {
	local -a devices
	bluetoothctl devices |
	while read _ MAC NAME; do
		devices+="${MAC//:/\\:}:${NAME//:/\\:}"
	done
	_describe -t devices 'device' devices
}

_bluezcomp_agentcap() {
	local -a agent_options=(${(f)"$(__bluetoothctl agent help)"})
	agent_options=( "${(@)agent_options:#(on|off)}" )
	compadd -a agent_options
}

_bluetoothctl_agent() {
	local -a agent_options=(${(f)"$(__bluetoothctl agent help)"})
	agent_options+=help
	compadd -a agent_options
}

_bluetoothctl_advertise() {
	local -a ad_options=(${(f)"$(__bluetoothctl advertise help)"})
	ad_options+=help
	compadd -a ad_options
}

_bluetoothctl() {
	local -a toggle_commands=(
		"discoverable" "pairable" "power" "scan"
	)

local -a controller_commands=(
		"select" "show"
	)

local -a device_commands=(
		"block" "connect" "disconnect" "info"
		"pair" "remove" "trust" "unblock" "untrust"
	)

# Other commands may be handled by _bluetoothctl_$command
	local -a all_commands=( "${(@f)$(__bluetoothctl --zsh-complete help)}" )

local curcontext=$curcontext state line ret=1
	_arguments -C \
		+ '(info)' \
		{-h,--help}'[Show help message and exit]' \
		{-v,--version}'--version[Show version info and exit]' \
		+ 'mod' \
		'(info)'{-a+,--agent=}'[Register agent handler]:agent:_bluezcomp_agentcap' \
		'(info)'{-t,--timeout}'[Timeout in seconds for non-interactive mode]' \
		'(info)'{-m,--monitor}'[Enable monitor output]' \
		+ 'command' \
		'(info):command:->command' \
		'(info):: :->argument'

if [[ $state == "command" ]]; then
		_describe -t commands 'command' all_commands
	elif [[ $state == "argument" ]]; then
		if (( ! ${"${(@)all_commands%%:*}"[(I)${line[1]}]} )); then
			_message "Unknown bluetoothctl command: $line[1]"
			return 1;
		fi

curcontext="${curcontext%:*:*}:bluetoothctl-$line[1]:"
		if ! _call_function ret _bluetoothctl_$line[1]; then
			case $line[1] in
				(${(~j.|.)toggle_commands})
					compadd on off
					;;
				(${(~j.|.)device_commands})
					_bluezcomp_device
					;;
				(${(~j.|.)controller_commands})
					_bluezcomp_controller
					;;
			esac
		fi
		return ret
	fi
} && _bluetoothctl